 /* Linker script for stm32f030r8 64k-flash + 8k-ram */

ENTRY(_start)

MEMORY
{
  rom (rx) : ORIGIN = 0x08000000, LENGTH = 64K
  ram (rw) : ORIGIN = 0x20000000, LENGTH =  8K
}

_stack = ORIGIN(ram) + LENGTH(ram);
_stack_bottom = _stack - 512;

SECTIONS {
	.text : {
		KEEP(*(.vectors)) 
		*(.text*)
		*(.rodata*)
		*(.init)
		__init_array_start = .;
		*(.init_array)
		__init_array_end = .;
		*(.fini .fini_array)
	} >rom 

	. = ALIGN(4);

	PROVIDE(_etext = .);
	
	.data : {
		_sdata = .;
		*(.data*)  *(.jcr)
		_edata = .;
	} >ram AT >rom

	.bss : {
		__bss_start__ = .; 
		*(.bss*)
		*(COMMON)
		__bss_end__ = .; 
		_end = .;
	} >ram
}	


